Mengambil Data Excel dengan VB6

Mengambil Data Excel dengan VB6

Dalam melakukan pengisian data pada sebuah transaksi (misalkan data stok opname) atactau pada saat melakukan migrasi data, sangat diperlukan kemudahan dalam melakukanya, sehingga proses yang dilakukan lebih mudah dan lebih cepat. Salah satu cara yang digunakan adalah dengan membaca data dari file lain, misalkan data dalam file Excel. Hal ini sangat mungkin dilakukan pada VB6, yaitu dengan cara memanfaatkan fasilitas dari reference yang disediakan oleh Microsoft Excel. Saya akan membahas tentang bagaimana cara mengambil data dari file excel berikut contoh source code yang bisa anda download.

Microsoft Excel Object Library

Jika dalam sistem operasi Windows anda terdapat program Microsoft Excel (Office), maka secara otomatis akan diaktifkan Active-X dari program Excel yang dapat kita pakai sebagai referensi untuk melakukan pekerjaan seperti halnya program Excel sendiri. Untuk itu pertama kali dalam program ini anda harus mengaktifkan library tersebut dengan menu Project dan References, kemudian pilih Microsoft Excel X.X Object Library, X.X adalah versi dari program Excel yang terinstal dalam Windows anda, seperti tampak pada gambar berikut ini:
Project References Excel
Dalam contoh seperti gambar diatas, saya menggunakan Microsoft Excel 12.0 Object Library.


Excel.Application

Microsoft Excel akan menyediakan object class Active-X yang bisa kita gunakan untuk memproses data-data dalam format excel, yaitu dengan cara cukup mengaktifkan object tersebut kedalam sebuah variable object, seperti contoh dalam kode program berikut ini:

'Membaca Data Excel
Private Sub ReadFileExcel()
    Dim Excel As New Excel.Application

Dan untuk membaca sebuah file excel, kita gunakan perintah dari class yang terdefinisi seperti contoh kode program diatas, dengan cara menggunakan perintah seperti kode program berikut ini:

    Excel.Workbooks.Open {nama-file-excel}, False, True
Nama file excel dapat anda tentukan atau anda gunakan komponen CommonDialog, sehingga anda bisa memilih file di folder dalam komputer anda.

Dan untuk membaca data dari sel excel dari file yang kita buka lewat perintah Workbooks.Open tersebut dilakukan dengan menggunakan perintah seperti kode program berikut ini:

    Excel.Cells({baris}, {kolom})
Baris dan kolom adalah alamat sel dari data dalam file excel yang kita maksud.

Untuk contoh lengkap dalam kode program mengambil data excel dengan VB6 adalah seperti berikut ini:

'Membaca Data Excel
Private Sub ReadFileExcel()
    Dim Excel As New Excel.Application
    
    Dim oData As ListItem
    Dim nRow As Integer
    
    Dim nColKodeBarang As Integer
    Dim nColNamaBarang As Integer
    Dim nColSatuan As Integer
    Dim nColStok As Integer
    Dim nColHargaJual As Integer
    
    Me.MousePointer = vbHourglass
        
    nColKodeBarang = 1
    nColNamaBarang = 2
    nColSatuan = 3
    nColStok = 4
    nColHargaJual = 5
    
    On Error GoTo ProsesError
    Excel.Workbooks.Open lblFileExcel.Caption, False, True
    lsvData.ListItems.Clear
    
    For nRow = 2 To 1000
        If Excel.Cells(nRow, nColKodeBarang) <> "" Then
           Set oData = lsvData.ListItems.Add
           
           oData.Text = Trim(Str(nRow - 1))
           oData.SubItems(nColKodeBarang) = Trim(Excel.Cells(nRow, nColKodeBarang))
           oData.SubItems(nColNamaBarang) = Trim(Excel.Cells(nRow, nColNamaBarang))
           oData.SubItems(nColSatuan) = Trim(Excel.Cells(nRow, nColSatuan))
           oData.SubItems(nColStok) = Format(Val(Excel.Cells(nRow, nColStok)), "###,##0")
           oData.SubItems(nColHargaJual) = Format(Val(Excel.Cells(nRow, nColHargaJual)), "###,##0")
        Else
            Exit For
        End If
    Next
        
    Excel.Workbooks.Close
    Excel.Quit
    Me.Refresh
    Me.MousePointer = vbDefault
    
    Set Excel = Nothing
    Exit Sub
    
ProsesError:
    MsgBox Err.Description, vbExclamation, "Peringatan"
    Excel.Workbooks.Close
    Excel.Quit
    Me.Refresh
    Me.MousePointer = vbDefault
    
    Set Excel = Nothing
End Sub

'Click Cari File Excel (CommonDialog)
Private Sub cmdExcel_Click()
    On Error Resume Next
    Dialog.InitDir = App.Path
    Dialog.Filter = " Report File | *.XLS"
    Dialog.ShowOpen
    If Trim(Dialog.FileName) <> "" Then
        lblFileExcel.Caption = Dialog.FileName
    End If
    On Error GoTo 0
End Sub

'Membaca Data File Excel
Private Sub cmdReadExcel_Click()
    ReadFileExcel
End Sub

Berikut source code contoh program aplikasi VB6 Mengambil Data Excel dengan VB6, yang bisa anda download disini. Jika anda masih belum jelas tentang program tersebut diatas, anda bisa bertanya pada kami lewat Contact Form atau dengan memberikan Komentar pada artikel ini.

Dan bagi yang masih awam tentang bahasa pemrograman VB6, anda bisa mengakses Tutorial VB6 yang telah kami posting sebelumnya.

Latest
Previous
Next Post »